AMD 8845HS 780M용 ComfyUI 포터블 버전 (TheRock버전)

최근에 8845hs로 AI 이미지 딸깍을 시도하려는 사람이 늘었는지 유입이 늘어서 물 들어 올때 노젓는다고 설치를 쉽게 만드는 포터블 딸깍 배치파일을 만들어 올려 봅니다. 그리고 폴더 구조를 좀 더 단순하게 정리 했습니다.

!!! VRAM을 16G 이상으로 세팅하는걸 권장합니다 !!!

2025년12월21일 추가

AMD 라데온 ROCM ComfyUI 포터블(?) 통합버전 스크립트

통합 스크립트를 작성했으니 위 링크 사용하는걸 추천합니다.

2025년 11월 5일 추가

ComfyUI가 업그레이드 되면서 780m으로 이미지 생성이 점점 느려지는걸 보고 구버전에 맞춰서 포터블 버전 압축해서 깃헙에 업로드 했습니다.

포터블 압축 파일은 아래 스크립트를 기반으로 작성되었으니 궁금하신 분들은 아래까지 읽어 보시면 되고 관심 없으신 분은 아래 깃헙링크로 가서 파일을 받아 압축풀고 run.bat 파일을 실행하면 됩니다.

https://github.com/Linsoo/ComfyUI_Portable/releases/tag/20251104_780m

1. 폴더 구조

폴더 구조를 미리 만들 필요 없습니다. 스크립트가 자동 생성합니다. 루트 폴더(C:\AI)만 만들면 됩니다.

/ETC : 필요한 프로그램을 다운 받아서 저장하는 폴더 입니다.

/ETC/ComfyUI : 컴피 프로그램 입니다.
/ETC/git : Git 프로그램입니다.
/ETC/python_embeded : 파이썬 3.12.10 임베디드 입니다. (커스텀 노드 설치 하다가 뭔가 꼬였다 싶으면 이 폴더를 날리고 “0_TheRock_Install.cmd” 파일을 다시 실행 하면 됩니다.)
/ETC/TMP_INSTALLER : git, python, pip cache, 및 기타 설치에 필요한 파일이 저장되는 폴더입니다.

/Models : 모델파일을 저장하는 폴더 입니다.

/Models/checkpoints : 체크포인트 저장 위치
/Models/loras : lora 저장 위치

/Outputs : 생성한 결과물이 저장되는 폴더 입니다.

/userdata : ComfyUI 설정값이 저장하는 폴더 입니다.

/userdata/custom-nodes : 커스텀 노드들이 저장되는 폴더입니다.
/userdata/default : ComfyUI 가 생성하는 폴더 (워크플로우나 기타 값들이 저장됩니다)

2. 설치 스크립트

스크립트는 원하는 폴더(ex: C:\AI) 에 넣고 실행 하면 됩니다.

단! 경로상에 한글이 들어가면 정상 작동하지 않습니다. (실행도 되고 연산도 하는데 결과가 위 처럼 나옵니다)

소스 복사 할때 드래그 하지 마시고 저 copy 버튼을 누르면 클립보드로 코드가 복사됩니다. 드래그 복사시 일부 특수 문자가 다르게 저장되서 오작동 할 수 있습니다.

0_TheRock_Install.cmd

@echo off
SETLOCAL ENABLEDELAYEDEXPANSION
chcp 65001 >nul
REM ---------------------------------------------------------------------------
REM 루트를 구함 ex) "c:\AI\"
set "PATH_ROOT=%~dp0"

set "PATH_PYTHON=%PATH_ROOT%ETC\python_embeded"
set "PATH_GIT=%PATH_ROOT%ETC\git"
set "PATH=%PATH_PYTHON%;%PATH_PYTHON%\Scripts;%PATH_GIT%;%PATH_GIT%\cmd;%SystemRoot%\System32;%SYSTEMROOT%\System32\WindowsPowerShell\v1.0\"

REM ---------------------------------------------------------------------------
REM 설치시 필요한 파일 저장하는 경로 (인터넷에서 두번 다운 받는거 안하기 위해)
set "PATH_TEMP_INSTALLER=%PATH_ROOT%ETC\TMP_INSTALLER" 
set "USERPROFILE=%PATH_TEMP_INSTALLER%\USERPROFILE"
REM ---------------------------------------------------------------------------
REM 컴피용
set "PATH_COMFYUI=%PATH_ROOT%ETC\ComfyUI"
set "PATH_COMFYUI_USER=%PATH_ROOT%userdata"
set "PATH_COMFYUI_CUSTOM_NODES=%PATH_COMFYUI_USER%\custom_nodes"
set "FILE_PATH_EXTRA_MODEL=%PATH_COMFYUI_USER%\extra_model_paths.yaml"
set "PATH_OUTPUTS=%PATH_ROOT%Outputs"

REM ---------------------------------------------------------------------------
REM 필수 폴더 생성

REM PATH_TEMP_INSTALLER 폴더 생성
if not exist "%PATH_TEMP_INSTALLER%" (
	mkdir "%PATH_TEMP_INSTALLER%"
)

REM USERPROFILE 폴더 생성
If Not Exist "%USERPROFILE%\AppData\Local\" (
    mkdir %USERPROFILE%\AppData\Local\
)
If Not Exist "%USERPROFILE%\AppData\LocalLow\" (
	mkdir %USERPROFILE%\AppData\LocalLow\
)
If Not Exist "%USERPROFILE%\AppData\Roaming\" (
	mkdir %USERPROFILE%\AppData\Roaming\
)

REM 컴피 유저 폴더 생성
if not exist "%PATH_COMFYUI_USER%" (
	mkdir "%PATH_COMFYUI_USER%"
)

REM 커스텀 노드 폴더 생성
if not exist "%PATH_COMFYUI_CUSTOM_NODES%" (
	mkdir "%PATH_COMFYUI_CUSTOM_NODES%"
)

REM 모델 체크포인트 폴더 생성
if not exist "%PATH_ROOT%Models\checkpoints" (
	mkdir "%PATH_ROOT%Models\checkpoints"
)

REM 모델 로라 폴더 생성
if not exist "%PATH_ROOT%Models\loras" (
	mkdir "%PATH_ROOT%Models\loras"
)

REM 결과 파일 폴더 생성
if not exist "%PATH_OUTPUTS%" (
	mkdir "%PATH_OUTPUTS%"
)


REM ---------------------------------------------------------------------------
if not exist "%FILE_PATH_EXTRA_MODEL%" (
	echo ---------------------------------------------------------------------------
	REM "C:\AI\" 제거 (주의: 끝에 \ 포함해야 정확히 제거됨)
	call set "TRIMMED=%%PATH_COMFYUI_CUSTOM_NODES:%PATH_ROOT%=%%"

	echo extra_model_paths.yaml 파일 생성
	(
		echo linsoo:
		echo.    base_path: C:\AI\
		echo.    is_default: true
		echo.    custom_nodes: !TRIMMED!/
		echo.
		echo.    checkpoints: Models/checkpoints/
		echo.    clip: Models/clip/
		echo.    clip_vision: Models/clip_vision/
		echo.    configs: Models/configs/
		echo.    controlnet: Models/control_net/
		echo.    diffusion_models: ^|
		echo.        Models/diffusion_models
		echo.        Models/unet
		echo.    embeddings: Models/embeddings/
		echo.    loras: Models/loras/
		echo.    upscale_models: Models/upscale_models/
		echo.    vae: Models/vae/
		echo.    ipadapter: Models/ipadapter/
		echo.    hypernetworks: Models/hypernetworks/
		echo.    sams: Models/sams/
		echo.    ultralytics: Models/ultralytics/
		echo.    ultralytics_bbox: Models/ultralytics/bbox/
		echo.    ultralytics_segm: Models/ultralytics/segm/
	) > "%FILE_PATH_EXTRA_MODEL%"
	echo 파일이 성공적으로 저장되었습니다: %FILE_PATH_EXTRA_MODEL%
)

REM ---------------------------------------------------------------------------
echo ---------------------------------------------------------------------------
echo 파이썬 체크
set "URL_PYTHON=https://www.python.org/ftp/python/3.12.10/python-3.12.10-embed-amd64.zip"
if not exist "%PATH_PYTHON%" (
	echo [INFO] 파이썬 폴더 없음
	if not exist "%PATH_TEMP_INSTALLER%\python_install.zip" (
		echo [INFO] Python 다운로드 중...
		curl -s -L "%URL_PYTHON%" -o "%PATH_TEMP_INSTALLER%\python_install.zip"
	)
	
	echo [INFO] 파이썬 압축 해제 중...
	mkdir "%PATH_PYTHON%"
	tar -xf "%PATH_TEMP_INSTALLER%\python_install.zip" -C "%PATH_PYTHON%"
	
	echo [INFO] 파이썬 설치 완료: %PATH_PYTHON%
) 

echo ---------------------------------------------------------------------------
echo Git 체크
set "URL_GIT=https://github.com/git-for-windows/git/releases/download/v2.50.1.windows.1/PortableGit-2.50.1-64-bit.7z.exe"
if not exist "%PATH_GIT%" (
	echo [INFO] Git 폴더 없음
	if not exist "%PATH_TEMP_INSTALLER%\Git_install.exe" (
		echo [INFO] Git 다운로드 중...
		curl -s -L "%URL_GIT%" -o "%PATH_TEMP_INSTALLER%\Git_install.exe"
	)
	
	echo [INFO] Git 압축 해제 중...
	mkdir "%PATH_GIT%"
	"%PATH_TEMP_INSTALLER%\Git_install.exe" -y -o"%PATH_GIT%"
	
	echo [INFO] Git 설치 완료: %PATH_GIT%
) 

echo ---------------------------------------------------------------------------
echo ComfyUI 체크
if not exist "%PATH_COMFYUI%\" (
	echo [INFO] ComfyUI 폴더 없음
	mkdir "%PATH_COMFYUI%"
	git.exe clone https://github.com/comfyanonymous/ComfyUI.git "%PATH_COMFYUI%"
	
	echo [INFO] 기타 ComfyUI 버그 방지용 작업
	mkdir "%PATH_COMFYUI%\user"
	REM 빈 comfyui.db 파일 생성
	type nul > "%PATH_COMFYUI%\user\comfyui.db"
	
	echo [INFO] ComfyUI 설치 완료: %PATH_COMFYUI%
)

REM 이 파일에서 주석처리를 해지 해야지만 pip 기능이 작동
echo ---------------------------------------------------------------------------
echo python312._pth 파일 수정

set "PTH_FILE=%PATH_PYTHON%\python312._pth"
set "TEMP_FILE=%PTH_FILE%.tmp"
set "COMFY_PATH=..\ComfyUI"

setlocal
	REM 파일 존재 확인
	if not exist "%PTH_FILE%" (
		echo [ERROR] 파일을 찾을 수 없습니다: %PTH_FILE%
		exit /b 1
	)

	set "comfy_exists=false"
	(
		for /f "usebackq delims=" %%A in ("%PTH_FILE%") do (
			set "line=%%A"

			REM '#import site' → 'import site'
			call set "line=%%line:#import site=import site%%"

			REM 중복된 ..\ComfyUI 제거
			if /i "!line!"=="%COMFY_PATH%" (
				set "comfy_exists=true"
				REM 건너뜀 (중복 제거)
			) else (
				echo !line!
			)
		)

		REM 마지막에 ..\ComfyUI 추가
		if "!comfy_exists!"=="false" (
			echo %COMFY_PATH%
		) else (
			REM 중복 제거했으니 다시 추가
			echo %COMFY_PATH%
		)

	) > "%TEMP_FILE%"

	REM 원본 파일 덮어쓰기
	move /Y "%TEMP_FILE%" "%PTH_FILE%" > nul

	echo [DONE] python312._pth 파일 수정 완료: %PTH_FILE%
endlocal

echo ---------------------------------------------------------------------------
echo PIP 설치

if not exist "%PATH_TEMP_INSTALLER%\get-pip.py" (
	echo [INFO] get-pip.py 없음, 다운로드 시작...
	curl -s -L "https://bootstrap.pypa.io/get-pip.py" -o "%PATH_TEMP_INSTALLER%\get-pip.py"
)
"%PATH_PYTHON%\python.exe" "%PATH_TEMP_INSTALLER%\get-pip.py" 
"%PATH_PYTHON%\python.exe" -s -m pip install --upgrade pip 
echo [INFO] PIP 설치 완료

echo ---------------------------------------------------------------------------
echo TheRock Torch 설치
setlocal
	set "url_therock=https://github.com/scottt/rocm-TheRock/releases/download/v6.5.0rc-pytorch-gfx110x/torch-2.7.0a0+git3f903c3-cp312-cp312-win_amd64.whl"
	for %%F in ("!url_therock!") do (
		set "FILENAME=%%~nxF"
	)

	if not exist "%PATH_TEMP_INSTALLER%\!FILENAME!" (
		echo [INFO] !FILENAME! 없음, 다운로드 시작...
		curl -s -L "%url_therock%" -o "%PATH_TEMP_INSTALLER%\!FILENAME!"
	)
	"%PATH_PYTHON%\python.exe" -s -m pip install "%PATH_TEMP_INSTALLER%\!FILENAME!" 
endlocal

echo ---------------------------------------------------------------------------
echo TheRock Torchaudio 설치
setlocal
	set "url_therock=https://github.com/scottt/rocm-TheRock/releases/download/v6.5.0rc-pytorch-gfx110x/torchaudio-2.6.0a0+1a8f621-cp312-cp312-win_amd64.whl"
	for %%F in ("!url_therock!") do (
		set "FILENAME=%%~nxF"
	)

	if not exist "%PATH_TEMP_INSTALLER%\!FILENAME!" (
		echo [INFO] !FILENAME! 없음, 다운로드 시작...
		curl -s -L "%url_therock%" -o "%PATH_TEMP_INSTALLER%\!FILENAME!"
	)
	"%PATH_PYTHON%\python.exe" -s -m pip install "%PATH_TEMP_INSTALLER%\!FILENAME!" 
endlocal

echo ---------------------------------------------------------------------------
echo TheRock Torchvision 설치
setlocal
	set "url_therock=https://github.com/scottt/rocm-TheRock/releases/download/v6.5.0rc-pytorch-gfx110x/torchvision-0.22.0+9eb57cd-cp312-cp312-win_amd64.whl"
	for %%F in ("!url_therock!") do (
		set "FILENAME=%%~nxF"
	)

	if not exist "%PATH_TEMP_INSTALLER%\!FILENAME!" (
		echo [INFO] !FILENAME! 없음, 다운로드 시작...
		curl -s -L "%url_therock%" -o "%PATH_TEMP_INSTALLER%\!FILENAME!"
	)
	"%PATH_PYTHON%\python.exe" -s -m pip install "%PATH_TEMP_INSTALLER%\!FILENAME!" 
endlocal

echo ---------------------------------------------------------------------------
"%PATH_PYTHON%\python.exe" -s -m pip install piexif numpy==1.26.4 

echo ---------------------------------------------------------------------------
echo "%PATH_COMFYUI%\requirements.txt" 설치
"%PATH_PYTHON%\python.exe" -s -m pip install -r "%PATH_COMFYUI%\requirements.txt" 

echo ---------------------------------------------------------------------------
pip list
echo https://linsoo.pe.kr/46694/
echo 설치 완료
echo ---------------------------------------------------------------------------
pause

설치 파일입니다. 파이썬, 깃, ComfyUI 등등 다양한 파일을 다운받아서 설치를 합니다.

1_TheRock_Update.cmd

@echo off
SETLOCAL ENABLEDELAYEDEXPANSION
chcp 65001 >nul
REM ---------------------------------------------------------------------------
REM 루트를 구함 ex) "c:\AI\"
set "PATH_ROOT=%~dp0"

set "PATH_PYTHON=%PATH_ROOT%ETC\python_embeded"
set "PATH_GIT=%PATH_ROOT%ETC\git"
set "PATH=%PATH_PYTHON%;%PATH_PYTHON%\Scripts;%PATH_GIT%;%PATH_GIT%\cmd;%SystemRoot%\System32;%SYSTEMROOT%\System32\WindowsPowerShell\v1.0\"

REM ---------------------------------------------------------------------------
REM 설치시 필요한 파일 저장하는 경로 (인터넷에서 두번 다운 받는거 안하기 위해)
set "PATH_TEMP_INSTALLER=%PATH_ROOT%ETC\TMP_INSTALLER" 
set "USERPROFILE=%PATH_TEMP_INSTALLER%\USERPROFILE"
REM ---------------------------------------------------------------------------
REM 컴피용
set "PATH_COMFYUI=%PATH_ROOT%ETC\ComfyUI"
set "PATH_COMFYUI_USER=%PATH_ROOT%userdata"
set "PATH_COMFYUI_CUSTOM_NODES=%PATH_COMFYUI_USER%\custom_nodes"
set "FILE_PATH_EXTRA_MODEL=%PATH_COMFYUI_USER%\extra_model_paths.yaml"
set "PATH_OUTPUTS=%PATH_ROOT%Outputs"

REM ---------------------------------------------------------------------------
REM 필수 폴더 생성

REM PATH_TEMP_INSTALLER 폴더 생성
if not exist "%PATH_TEMP_INSTALLER%" (
	mkdir "%PATH_TEMP_INSTALLER%"
)

REM USERPROFILE 폴더 생성
If Not Exist "%USERPROFILE%\AppData\Local\" (
    mkdir %USERPROFILE%\AppData\Local\
)
If Not Exist "%USERPROFILE%\AppData\LocalLow\" (
	mkdir %USERPROFILE%\AppData\LocalLow\
)
If Not Exist "%USERPROFILE%\AppData\Roaming\" (
	mkdir %USERPROFILE%\AppData\Roaming\
)

REM 컴피 유저 폴더 생성
if not exist "%PATH_COMFYUI_USER%" (
	mkdir "%PATH_COMFYUI_USER%"
)

REM 커스텀 노드 폴더 생성
if not exist "%PATH_COMFYUI_CUSTOM_NODES%" (
	mkdir "%PATH_COMFYUI_CUSTOM_NODES%"
)

REM ---------------------------------------------------------------------------

"%PATH_PYTHON%\python.exe" -s -m pip install --upgrade pip 
echo ---------------------------------------------------------------------------
echo ComfyUI 업데이트

git.exe -C "%PATH_COMFYUI%" pull
"%PATH_PYTHON%\python.exe" -s -m pip install -r "%PATH_COMFYUI%\requirements.txt" 
echo.

REM ---------------------------------------------------------------------------
REM 커스텀노드 업데이트 체크
for /f "tokens=*" %%G in ('dir /b /a:d "%PATH_COMFYUI_CUSTOM_NODES%"') do ( 
	echo ---------------------------------------------------------------------------
	echo %%G
	git.exe -C "%PATH_COMFYUI_CUSTOM_NODES%\%%G" pull
	
	if exist "%PATH_COMFYUI_CUSTOM_NODES%\%%G\requirements.txt" (
		"%PATH_PYTHON%\python.exe" -s -m pip install -r "%PATH_COMFYUI_CUSTOM_NODES%\%%G\requirements.txt" 
	)
	echo .
)

echo ---------------------------------------------------------------------------
echo https://linsoo.pe.kr/46694/
echo 업데이트 완료
echo ---------------------------------------------------------------------------
pause

ComfyUI와 커스텀 노드 업데이트를 합니다.

ComfyUI는 거의 매일 업데이트가 되고 있는데 (개발진이 일정 주기로 sync 하는게 아니라 그냥 커밋하고 바로 바로 올리는듯) ComfyUI의 업데이트 속도를 커스텀 노드가 못 따라가서 문제 생기는 경우가 있기 때문에 커스텀 노드 많이 쓰시는 분은 가끔 업데이트 하는걸 추천드립니다.

2_TheRock_extra_install.cmd

@echo off
SETLOCAL ENABLEDELAYEDEXPANSION
chcp 65001 >nul
REM ---------------------------------------------------------------------------
REM 루트를 구함 ex) "c:\AI\"
set "PATH_ROOT=%~dp0"

set "PATH_PYTHON=%PATH_ROOT%ETC\python_embeded"
set "PATH_GIT=%PATH_ROOT%ETC\git"
set "PATH=%PATH_PYTHON%;%PATH_PYTHON%\Scripts;%PATH_GIT%;%PATH_GIT%\cmd;%SystemRoot%\System32;%SYSTEMROOT%\System32\WindowsPowerShell\v1.0\"

REM ---------------------------------------------------------------------------
REM 설치시 필요한 파일 저장하는 경로 (인터넷에서 두번 다운 받는거 안하기 위해)
set "PATH_TEMP_INSTALLER=%PATH_ROOT%ETC\TMP_INSTALLER" 
set "USERPROFILE=%PATH_TEMP_INSTALLER%\USERPROFILE"
REM ---------------------------------------------------------------------------
REM 컴피용
set "PATH_COMFYUI=%PATH_ROOT%ETC\ComfyUI"
set "PATH_COMFYUI_USER=%PATH_ROOT%userdata"
set "PATH_COMFYUI_CUSTOM_NODES=%PATH_COMFYUI_USER%\custom_nodes"
set "FILE_PATH_EXTRA_MODEL=%PATH_COMFYUI_USER%\extra_model_paths.yaml"
set "PATH_OUTPUTS=%PATH_ROOT%Outputs"

REM ---------------------------------------------------------------------------
REM 필수 폴더 생성

REM PATH_TEMP_INSTALLER 폴더 생성
if not exist "%PATH_TEMP_INSTALLER%" (
	mkdir "%PATH_TEMP_INSTALLER%"
)

REM USERPROFILE 폴더 생성
If Not Exist "%USERPROFILE%\AppData\Local\" (
    mkdir %USERPROFILE%\AppData\Local\
)
If Not Exist "%USERPROFILE%\AppData\LocalLow\" (
	mkdir %USERPROFILE%\AppData\LocalLow\
)
If Not Exist "%USERPROFILE%\AppData\Roaming\" (
	mkdir %USERPROFILE%\AppData\Roaming\
)

REM 컴피 유저 폴더 생성
if not exist "%PATH_COMFYUI_USER%" (
	mkdir "%PATH_COMFYUI_USER%"
)

REM 커스텀 노드 폴더 생성
if not exist "%PATH_COMFYUI_CUSTOM_NODES%" (
	mkdir "%PATH_COMFYUI_CUSTOM_NODES%"
)

REM ---------------------------------------------------------------------------
REM 여기는 pip로 설치해야 하는거

REM "%PATH_PYTHON%\python.exe" -s -m pip install timm numpy==1.26.4 debugpy
REM "%PATH_PYTHON%\python.exe" -s -m pip list


REM ---------------------------------------------------------------------------
cd %PATH_COMFYUI_CUSTOM_NODES%

REM 여기는 커스텀 노드 추가 할거
REM git.exe clone "https://github.com/huchenlei/ComfyUI-openpose-editor.git"

cd "%PATH_ROOT%"
echo ---------------------------------------------------------------------------
echo https://linsoo.pe.kr/46694/
echo 설치 완료
echo ---------------------------------------------------------------------------
pause

모듈이 없다고 나올때 여기에 모듈을 넣고 실행하거나 커스텀 노드에 git clone 받을때 편하게 쓸려고 만들었습니다. 만약 커스텀 모듈에 requirements.txt 파일이 있다면 2_TheRock_extra_install.cmd를 한번 실행 해주면 해당 모듈을 설치합니다.

3_TheRock_Run.cmd

@echo off
SETLOCAL ENABLEDELAYEDEXPANSION
chcp 65001 >nul
REM ---------------------------------------------------------------------------
REM 루트를 구함 ex) "c:\AI\"
set "PATH_ROOT=%~dp0"

set "PATH_PYTHON=%PATH_ROOT%ETC\python_embeded"
set "PATH_GIT=%PATH_ROOT%ETC\git"
set "PATH=%PATH_PYTHON%;%PATH_PYTHON%\Scripts;%PATH_GIT%;%PATH_GIT%\cmd;%SystemRoot%\System32;%SYSTEMROOT%\System32\WindowsPowerShell\v1.0\"

REM ---------------------------------------------------------------------------
REM 설치시 필요한 파일 저장하는 경로 (인터넷에서 두번 다운 받는거 안하기 위해)
set "PATH_TEMP_INSTALLER=%PATH_ROOT%ETC\TMP_INSTALLER" 
set "USERPROFILE=%PATH_TEMP_INSTALLER%\USERPROFILE"
REM ---------------------------------------------------------------------------
REM 컴피용
set "PATH_COMFYUI=%PATH_ROOT%ETC\ComfyUI"
set "PATH_COMFYUI_USER=%PATH_ROOT%userdata"
set "PATH_COMFYUI_CUSTOM_NODES=%PATH_COMFYUI_USER%\custom_nodes"
set "FILE_PATH_EXTRA_MODEL=%PATH_COMFYUI_USER%\extra_model_paths.yaml"
set "PATH_OUTPUTS=%PATH_ROOT%Outputs"

REM ---------------------------------------------------------------------------


REM ---------------------------------------------------------------------------
REM 필수 폴더 생성

REM PATH_TEMP_INSTALLER 폴더 생성
if not exist "%PATH_TEMP_INSTALLER%" (
	mkdir "%PATH_TEMP_INSTALLER%"
)

REM USERPROFILE 폴더 생성
If Not Exist "%USERPROFILE%\AppData\Local\" (
    mkdir %USERPROFILE%\AppData\Local\
)
If Not Exist "%USERPROFILE%\AppData\LocalLow\" (
	mkdir %USERPROFILE%\AppData\LocalLow\
)
If Not Exist "%USERPROFILE%\AppData\Roaming\" (
	mkdir %USERPROFILE%\AppData\Roaming\
)

REM 컴피 유저 폴더 생성
if not exist "%PATH_COMFYUI_USER%" (
	mkdir "%PATH_COMFYUI_USER%"
)

REM 커스텀 노드 폴더 생성
if not exist "%PATH_COMFYUI_CUSTOM_NODES%" (
	mkdir "%PATH_COMFYUI_CUSTOM_NODES%"
)

REM 모델 체크포인트 폴더 생성
if not exist "%PATH_ROOT%Models\checkpoints" (
	mkdir "%PATH_ROOT%Models\checkpoints"
)

REM 모델 로라 폴더 생성
if not exist "%PATH_ROOT%Models\loras" (
	mkdir "%PATH_ROOT%Models\loras"
)

REM 결과 파일 폴더 생성
if not exist "%PATH_OUTPUTS%" (
	mkdir "%PATH_OUTPUTS%"
)

REM 변경된 루트 폴더 위치에 맞게 모델파일 경로 변경
if exist "%FILE_PATH_EXTRA_MODEL%" (
    set "EXTRA_MODEL_PATH_LINE=base_path: %PATH_ROOT%"
    powershell -NoProfile -Command ^
        "$file = '%FILE_PATH_EXTRA_MODEL%';" ^
        "$newLine = 'base_path: %PATH_ROOT%';" ^
        "$text = Get-Content -LiteralPath $file -Raw;" ^
        "$text = $text -replace 'base_path: .*', $newLine;" ^
        "$utf8 = New-Object System.Text.UTF8Encoding($false);" ^
        "[System.IO.File]::WriteAllText($file, $text, $utf8)"
)

echo ---------------------------------------------------------------------------
set COMMANDLINE_ARGS=--use-pytorch-cross-attention --highvram --fp16-vae --preview-method auto --output-directory "%PATH_OUTPUTS%" --user-directory "%PATH_COMFYUI_USER%" --extra-model-paths-config "%FILE_PATH_EXTRA_MODEL%" 

"%PATH_PYTHON%\python.exe" -s  "%PATH_COMFYUI%\main.py" %COMMANDLINE_ARGS% 
echo ---------------------------------------------------------------------------
echo https://linsoo.pe.kr/46694/
echo ---------------------------------------------------------------------------
pause

ComfyUI 실행 파일입니다.

3. 마무리

설명이 부실하지만 이번에도 마찬가지로 근성과 기합 그리고 노오오오오오력으로 극복하시길 바랍니다.

초차원게임 이스투아르.. 대충 보면 그럴듯 한데 자세히 따져보면 초차원이랑 신차원이랑 다 합쳐 놓았네…

어른 넵튠

내가 넵튠 플레이 한지 오래 되서 기억이 가물가물하긴 하지만 대충 뽑은 그림인데 게임 일러스트 느낌이 난다.

뒤에 대형 공룡뼈가 있는 자연사 박물관이 나오길 기대 했지만 그냥 작은 공룡 하나 나오고 끝…

맥주잔 들은 공룡 티셔츠!

느와르…

스쿼트 로라 쓴건데 게임 스샷 같음 ㅋㅋㅋ

스튜어디스 복장 블랑…

ComfyUI를 쓰면 거의 기본으로 쓴다는 ComfyUI-Manager를 포함 하지 않는 이유는 써보면 편하긴 한데 AI 이미지 생성은 기본적으로 엔비디아 쓴다고 가정하고 만들어서 그런지 커스텀 노드 중에 requirements.txt 있고 안에 설치해야 하는 모듈이 많을 경우 제대로 작동 안될 확률이 매우 높습니다. 그래서 노드 몇개 깔았더니 무슨 모듈 없다고 작동을 안하고 실행 할때 계속 모듈 충돌 경고가 뜹니다.

가급적 코어 노드 활용을 추천드리고요. 제가 추천하는 커스텀 노드는 아래와 같습니다.

Comments

10의 “AMD 8845HS 780M용 ComfyUI 포터블 버전 (TheRock버전)”에 대한 답변

guest

2025년 8월 4일

이전 게시물들 보고나서 컴퓨터 언어를 모르는 비전공자 입장이라
‘어떻게 해야하지…. 이전게시물도.. 에러도 나고.. 안되는데…’ 이러고 있었는데,
올인원 자료주셔서 감사합니다!

답글
1. Linsoo
  
  2025년 8월 4일
  
  Comfy도 Python도 그렇고 다들 정신없이 업데이트를 해나가면서 뭔가 삐그덕 하는가 보군요.
  예전에 글 작성할때 작동하는거 확인하고 올렸는데.
2. guest
  
  2025년 8월 4일
  
  아!그리고 깜빡했는데
  
  ComfyUI -> custom_nodes 폴더에서
  git clone https://github.com/ltdrdata/ComfyUI-Manager.git
  실행해서 manager를 추가하면 좋을거 같습니다.^^
3. Linsoo
  
  2025년 8월 4일
  
  그거 글 끝에 써 놓았습니다. 안 넣은 이유를요.
guest

2025년 8월 6일

이유를 마지막에 넣었습니다.
제가 ‘컴퓨터 언어를 모르는 비전공자이다보니’ 확실히
허깅페이스에서 가져온 모델들도 그렇고 다른곳에서 가져온 json 파일로 템플릿?을 불러와서
사용해보려니 상당한 에러들이 많이 발생해서 8845hs cpu의 780m으로는..
아직 사용을 못해보겠더라구요. [특히 이번에 오픈소스로 공개된 wan 2.2 나 2.1을 써보고 싶었던..]

그래도 이런 올인원 코드롤 amd gpu[igpu] 에서 사용가능토록 올려주셔서 감사합니다.

[별도내용]

혹시 comfyui 나 스테이블 디퓨전류 말고
llm ai 구동을 위한 LM Studio 나 ollama 에서도 해당 igpu의 780M 를
ROCm 으로 구동할 수 있는 방법이 있다면,, 게시물정보에 올려주실 수 있을지 여쭤봅니다.

답글
1. Linsoo
  
  2025년 8월 6일
  
  저도 해보니깐 꼬여서 오히려 되던게 안되던 문제가 많이 일어나서요. 그래서 매니저 사용을 비추한 것입니다. wan은 커뮤니티 글 보니 780m으로는 많이 힘들거 같습니다. 780m 보다 몇배 이상 빠른 엔비디아 시리즈 카드 가지고도 시간 오래 걸린다는거 보면 말이죠.
  
  LLM쪽은 제가 아직 시도 안해봤습니다. 나중에 해보게 되면 그리고 가능하다면 올려보도록 하죠.
guest

2025년 10월 7일

안녕하세요.
ConfyUI-portable 버전에서 AMD버전 패키지가 릴 된거 같습니다.
Linsoo님이 제공해주신 버전만큼 괜찮을진 모르겠지만, 혹시나해서 링크 남겨봅니다.
https://github.com/comfyanonymous/ComfyUI/releases/tag/v0.3.63

답글
1. Linsoo
  
  2025년 10월 8일
  
  몇일전에 해봤는데 일단 저거 파이토치 프리뷰 드라이버를 설치해야 하는데 780m은 미지원입니다.
  9070으로 돌리면 작동은 하는데 속도가 780m이랑 비슷하게 나옵니다.
  
  제 예상으론 나중에도 780m은 지원안할겁니다.
  comfy는 amd가 공식 지원하는 rocm을 가져다 쓸텐데 amd는 스트릭 헤일로나 AI 맥스? 이거 하위버전은 관심이 없더군요.
  
  9070이 있으시다면 나이틀리 빌드 찍먹 하는것도 추천드립니다. https://linsoo.pe.kr/47016/
  현재 많이 불안정해서 그렇지 안정화만 되면 상당히 기대되는 퍼포먼스가 나오긴 합니다.
익명

2025년 10월 30일

남는 W6800에서 SD3.5 1024×1024 생성속도가 32.88s/it로 처참하네요. 작성해주신 스크립트가 작동하지 않아서 그래픽카드 세대차이일 것 같아 파이선이나 torch 버전을 gfx1030 지원하는 버전으로 사용해서일까요?

답글
1. Linsoo
  
  2025년 10월 30일
  
  W6800에서 속도 잘나오는 torch 버전을 찾아야 할겁니다. 위 스크립트에서 설치하는 torch는 9070으로 돌렸을때 제대로 동작하지 않고 속도도 느렸습니다.

답글 남기기 응답 취소

이 사이트는 Akismet을 사용하여 스팸을 줄입니다. 댓글 데이터가 어떻게 처리되는지 알아보세요.